И снова к интересному ))
Всё на тех же просторах интернета нарыл интересный контроллер для самого необходимого, никаких наворотов, никаких супер пупер функций, все предельно просто:
6 каналов ШИМ с функцией рассвет-закат
Скрытый текст
Главная задача блока управления – плавная регулировка уровня по каждому каналу индивидуально в соответствии с заданными данными по каждому каналу в режиме реального времени (по DS1307):
- время начало рассвета;
- время окончания рассвета;
- время начала заката;
- время окончания рассвета;
- минимальное значение ШИМ (ночной период);
- максимальное значение ШИМ (дневной период).
Соответственно, ШИМ сигнал на драйвер канала:
- в ночное время минимальное значение;
- в дневное время максимальное значение;
- в период рассвета линейно увеличивается от минимального к максимальному значению;
- в период заката линейно уменьшается от максимального к минимального значению.
2 канала (реле) - вентиляторы и лунная подсветка
2 канала (реле) - на что угодно, настраиваются на любое время.
Для всего этого нам потребуется всего ничего :
Arduino Nano 3.0 -
http://ru.aliexpress.com/item/Nano-3...272435407.html
RTC ds1307 часы реального времени -
http://ru.aliexpress.com/item/1pcs-M...7-d444767a6c23
4-канальный релейный модуль -
http://ru.aliexpress.com/item/Free-S...999.277.8dfywV Рекомендую именно этот модуль, так как в нём есть H / L триггер, переключатель входного сигнала. И тогда не нужно будет переписывать программу, подключать "наоборот" или ещё разные выдумки.
Как видите, имея всего 7.5$ Вы можете собрать вполне хороший контроллер ...
Полностью прост и надёжен, хоть есть нюанс - для корректировки яркости и настройки силовых каналов, нужно каждый раз подключать к компу, вносить изменения в скетч и заливать на контроллер. Хотя знаю что после нескольких настроек, Вы полностью довольные картинкой и работой - просто туда не будет необходимости ещё что-то настраивать )))
Итак к сборке, и снова всё предельно просто -
Часы / Arduino : SDA / A4 , SCL / A5 , VCC / +5V , GND / GND
ШИМ каналы подключаются на пины : D3, D5, D6, D9, D10,D11
Каналы реле: на ардуине - D7, D8 ( вентилятор и лунн.подсв), D4, D12 (любые другие нагрузки), +5V и GND , на реле IN1,IN2,IN3,IN4 (или CTR1,CTR2,CTR3,CTR4) , VCC и GND
Для программирования потребуется : Среда разработки для Arduino 1.0.5 (
https://www.arduino.cc/en/Main/OldSo...Releases#1.0.x ), библиотека RTC (во вложении) и драйвер для Вашего - Arduino (у меня WIN 10 сам определил и установил драйвер, если что в сети легко найти)
Программирование:
Сначала выполняем скетч для запуска часов, дату вводите свою !! -
Скрытый текст
#include <Wire.h>
#include "RTClib.h"
RTC_DS1307 RTC;
void setup()
{
Serial.begin(57600);
Wire.begin();
RTC.begin();
RTC.adjust(DateTime(2013, 8, 6, 10, 30, 1)); //Установка даты и времени в формате год, месяц, день, час, минута, сек.
}
void loop () {
DateTime now = RTC.now();
Serial.print(now.year(), DEC);
Serial.print('/');
Serial.print(now.month(), DEC);
Serial.print('/');
Serial.print(now.day(), DEC);
Serial.print(' ');
Serial.print(now.hour(), DEC);
Serial.print(':');
Serial.print(now.minute(), DEC);
Serial.print(':');
Serial.print(now.second(), DEC);
Serial.println();
delay(1000);
}
Проверяете в мониторе порта - правильность настройки времени, после этого загружаем скетч :
Скрытый текст
#include <Wire.h>
#include "RTClib.h"
RTC_DS1307 RTC;
int Hours_Start_Relay34[2] = {11, 12}; // включение реле 3 и 4 час
int Minutes_Start_Relay34[2] = {0, 0}; // включение реле 3 и 4 минута
int Hours_End_Relay34[2] = {20, 21}; // выключение реле 3 и 4 час
int Minutes_End_Relay34[2] = {0, 0}; // выключение реле 3 и 4 минута
int MinuteDay_Start_Relay34[2]; // день в минутах для включения реле 3 и 4
int MinuteDay_End_Relay34[2]; // день в минутах для выключения реле 3 и 4
int Hours_Start_Sunrise[6] = {11, 9, 10, 11, 12, 12}; // начало рассвета по каналам час
int Minutes_Start_Sunrise[6] = {0, 0, 0, 0, 0, 0}; // начало рассвета по каналам минута
int Hours_End_Sunrise[6] = {14, 11, 12, 13, 14, 14}; // окончание рассвета по каналам час
int Minutes_End_Sunrise[6] = {0, 0, 0, 0, 0, 0}; // окончание рассвета по каналам минута
int Hours_Start_Sunset[6] = {18, 21, 20, 19, 18, 18}; // начало заката по каналам час
int Minutes_Start_Sunset[6] = {0, 0, 0, 0, 0, 0}; // начало заката по каналам минута
int Hours_End_Sunset[6] = {21, 22, 22, 21, 21, 21}; // окончание заката по каналам час
int Minutes_End_Sunset[6] = {0, 30, 0, 0, 0, 0}; // окончание заката по каналам минута
int MinuteDay_Start_Sunrise[6]; // день в минутах для начала рассвета
int MinuteDay_End_Sunrise[6]; // день в минутах для окончания рассвета
int MinuteDay_Start_Sunset[6]; // день в минутах для начала заката
int MinuteDay_End_Sunset[6]; // день в минутах для окончания заката
int Current_MinuteDay; // текущая минута суток
int Current_Period[6]; // текущая часть суток 1-рассвет, 2-день, 3-закат, 4-ночь для каждого ШИМ
//int Meridian_PWM[6] = {128, 192, 192, 192, 128, 128}; // максимальное значение ШИМ
int Meridian_PWM[6] = {255, 255, 255, 255, 5, 255}; // максимальное значение ШИМ
int Midnight_PWM[6] = {0, 0, 0, 0, 0, 0}; // минимальное значение ШИМ
int Current_PWM[6] = {0, 0, 0, 0, 0, 0}; // текущее значение ШИМ
/* ************************************************** *** */
/* * * */
/* * ШИМ пин для CW, TV, RB, NB, DR, NG * */
/* * Пин - 3 - CW - Cool White * */
/* * Пин - 5 - TV - True Violet * */
/* * Пин - 6 - RB - Royal Blue * */
/* * Пин - 7 - NB - Blue * */
/* * Пин - 10 - DR - Deep Red * */
/* * Пин - 11 - NG - Green * */
/* * * */
/* ************************************************** *** */
int PWM_Pin[6] = {3, 5, 6, 9, 10, 11}; // ШИМ пин для CW, TV, RB, NB, DR, NG
int Relay1 = 7; //вент
int Relay2 = 8; //луна
byte Relay1Status=false;
byte Relay2Status=false;
int Relay34[2] = {4, 12}; //Реле 3 и 4
byte Relay34Status[2] = {false, false};
void setup()
{
Serial.begin(57600);
Wire.begin();
RTC.begin();
if (! RTC.isrunning()) {
Serial.println("RTC is NOT running!");
// following line sets the RTC to the date & time this sketch was compiled
RTC.adjust(DateTime(2013, 1, 1, 12, 59, 1));
}
//RTC.adjust(DateTime(2013, 1, 1, 12, 59, 1));
for (int i=0; i<=5; i++)
{
pinMode(PWM_Pin[i], OUTPUT); // Установка пин для ШИМ
}
for (int i=0; i<=5; i++)
{
analogWrite(PWM_Pin[i], Midnight_PWM[i]); // Установка минимального значения ШИМ
Current_PWM[i]=Midnight_PWM[i]; // установка текущих значений ШИМ в минимум
}
for (int i=0; i<=5; i++)
{
MinuteDay_Start_Sunrise[i]=60*Hours_Start_Sunrise[i] + Minutes_Start_Sunrise[i]; // Расчет минуты суток для начала рассвета
MinuteDay_End_Sunrise[i]=60*Hours_End_Sunrise[i] + Minutes_End_Sunrise[i]; // Расчет минуты суток для окончания рассвета
MinuteDay_Start_Sunset[i]=60*Hours_Start_Sunset[i] + Minutes_Start_Sunset[i]; // Расчет минуты суток для начала заката
MinuteDay_End_Sunset[i]=60*Hours_End_Sunset[i] + Minutes_End_Sunset[i]; // Расчет минуты суток для окончания заката
}
for (int i=0; i<=1; i++)
{
MinuteDay_Start_Relay34[i]=60*Hours_Start_Relay34[i] + Minutes_Start_Relay34[i]; // Расчет минуты суток для включения реле 3 и 4
MinuteDay_End_Relay34[i]=60*Hours_End_Relay34[i] + Minutes_End_Relay34[i]; // Расчет минуты суток для выключения реле 3 и 4
pinMode(Relay34[i], OUTPUT);
digitalWrite(Relay34[i], LOW);
}
pinMode(Relay1, OUTPUT);
pinMode(Relay2, OUTPUT);
digitalWrite(Relay1, LOW);
digitalWrite(Relay2, HIGH);
}
// Процедура расчета текущего периода и значения PWM по каналам
void Led_Dim_PWM()
{
DateTime now = RTC.now();
Current_MinuteDay = (now.hour() * 60) + now.minute();
for (int i=0; i<=5; i++)
{
Current_Period[i]=4;
if (Current_MinuteDay>=MinuteDay_Start_Sunrise[i] && Current_MinuteDay<=MinuteDay_End_Sunrise[i]) {Current_Period[i]=1;}
if (Current_MinuteDay>MinuteDay_End_Sunrise[i] && Current_MinuteDay<MinuteDay_Start_Sunset[i]) {Current_Period[i]=2;}
if (Current_MinuteDay>=MinuteDay_Start_Sunset[i] && Current_MinuteDay<=MinuteDay_End_Sunset[i]) {Current_Period[i]=3;}
if (Current_Period[i]==1)
{
Current_PWM[i]=(float)(((float)Current_MinuteDay-MinuteDay_Start_Sunrise[i])/((float)MinuteDay_End_Sunrise[i]-MinuteDay_Start_Sunrise[i]))*((float)Meridian_PWM[i]-Midnight_PWM[i]);
if (Current_PWM[i]<Midnight_PWM[i]) {Current_PWM[i]=Midnight_PWM[i];}
analogWrite(PWM_Pin[i], Current_PWM[i]);
}
if (Current_Period[i]==2)
{
if (Current_PWM[i]!=Meridian_PWM[i])
{
Current_PWM[i]=Meridian_PWM[i];
analogWrite(PWM_Pin[i], Current_PWM[i]);
}
}
if (Current_Period[i]==3)
{
Current_PWM[i]=(float)(((float)MinuteDay_End_Sunset[i]-Current_MinuteDay)/((float)MinuteDay_End_Sunset[i]-MinuteDay_Start_Sunset[i]))*((float)Meridian_PWM[i]-Midnight_PWM[i]);
analogWrite(PWM_Pin[i], Current_PWM[i]);
}
if (Current_Period[i]==4)
{
if (Current_PWM[i]!=Midnight_PWM[i])
{
Current_PWM[i]=Midnight_PWM[i];
if (Current_PWM[i]<Midnight_PWM[i]) {Current_PWM[i]=Midnight_PWM[i];}
analogWrite(PWM_Pin[i], Current_PWM[i]);
}
}
}
Serial.print(now.year(), DEC);
Serial.print('/');
Serial.print(now.month(), DEC);
Serial.print('/');
Serial.print(now.day(), DEC);
Serial.print(' ');
Serial.print(now.hour(), DEC);
Serial.print(':');
Serial.print(now.minute(), DEC);
Serial.print(':');
Serial.print(now.second(), DEC);
Serial.print(" Current_MinuteDay: ");
Serial.print(Current_MinuteDay, DEC);
Serial.println();
for (int i=0; i<=5; i++)
{
Serial.print("Channel #");
Serial.print(i, DEC);
// Serial.println();
Serial.print(", Current Period: ");
if (Current_Period[i]==1) {Serial.print("Sunrise");}
if (Current_Period[i]==2) {Serial.print("Meridian");}
if (Current_Period[i]==3) {Serial.print("Sunset");}
if (Current_Period[i]==4) {Serial.print("Midnight");}
Serial.print(", Current PWM: ");
Serial.print(Current_PWM[i], DEC);
Serial.println();
}
Serial.println();
}
void RalayOnOff()
{
int SumPWM=0;
for (int i=0; i<=5; i++)
{
SumPWM=SumPWM+Current_PWM[i];
}
if (SumPWM>=50 && Relay1Status==false)
{
Relay1Status=true;
Relay2Status=false;
digitalWrite(Relay1, HIGH);
digitalWrite(Relay2, LOW);
}
if (SumPWM<50 && Relay1Status==true)
{
Relay1Status=false;
Relay2Status=true;
digitalWrite(Relay1, LOW);
digitalWrite(Relay2, HIGH);
}
}
void Ralay34OnOff()
{
for (int i=0; i<=1; i++)
{
if (Current_MinuteDay>=MinuteDay_Start_Relay34[i] && Current_MinuteDay<=MinuteDay_End_Relay34[i])
{
if (Relay34Status[i]==false)
{
Relay34Status[i]=true;
digitalWrite(Relay34[i], HIGH);
}
}
if (Current_MinuteDay<MinuteDay_Start_Relay34[i] || Current_MinuteDay>MinuteDay_End_Relay34[i])
{
if (Relay34Status[i]==true)
{
Relay34Status[i]=false;
digitalWrite(Relay34[i], LOW);
}
}
}
}
void loop () {
if ( ( millis() % 30000 ) == 0 )
{
Led_Dim_PWM();
RalayOnOff();
Ralay34OnOff();
}
}
Вот и всё )))
Полюбому что-то мог пропустить, если что спрашивайте, вместе разберёмся ))
Кстати, каналы вентилятора и лунной подсветки я так понимаю каким-то образом привязаны к времени освещения, то-есть, если вентилятор включается с включением света, а луна с выключением света - то логично попробовать (ну кому это нужно конечно
) подключить СО2 и компрессор соответственно, таким образом ещё 2 канала свободных под что-то ))